Gunther Oracle APEX und Datenbank Wiki

Diese Seite ist nicht editierbar. Sie können den Quelltext sehen, jedoch nicht verändern. Kontaktieren Sie den Administrator, wenn Sie glauben, dass hier ein Fehler vorliegt.
=====PL/SQL - Eine DB Session "schlafen" legen - Wie und welche Sleep Funktion einsetzen? =====


Aufgabe: Eine Datenbank Session soll mit einer sleep Funktion eine gewisse Zeit pausiert werden.

Z.B. in einem Monitoring Job, der jede Minute prüfen ob ein andere Job noch aktiv ist und keine Fehler geworfen hat. 



**Möglichkeiten:**

**APEX Installiert:**
  * APEX_UTIL.pause ( aber <fc #800000>nur bis maximal 120 Sekunden!</fc> , Wait Event "PL/SQL lock timer") 

**DB Version vor 18c:**
  * Java über java.lang.Thread.sleep  ( <fc #800000>Waits Events in der Statistik</fc> sichtbar, nicht verwirren lassen!)
  * DBMS_LOCK.sleep (<fc #800000>Sicherheitsproblem</fc> mit generellen Zugriff auf das Package DBMS_LOCK, Wait Event "PL/SQL lock timer"))


**DB Version ab 18c**
  * DBMS_SESSION.sleep  ( so sollte es schon immer sein ... ) 



----



====APEX_UTIL.pause====

Ist in der DB APEX installiert, kann auf APEX_UTIL zurückgegriffen werden.

10 Sekunden warten:
<code plsql>
begin
 APEX_UTIL.PAUSE(10);
end;
/
</code>

Jetzt ist nur die Frage, wie das intern umgesetzt wird.
Das Synonym "APEX_UTIL" zeigt jedenfalls auf das Package "htmldb_util" und von da auf "WWV_FLOW_UTILITIES.PAUSE", dort wird dann "SYS.DBMS_LOCK.SLEEP(L_SECONDS);" gekapselt.

Und alle Werte über 120 Sekunden werden mit dem Default 120 Sekunden überschrieben!

D.h. die maximale Wartezeit beträgt 120 Sekunden.

Eigene Routine um auch länger als 120s warten zu können und dann ab der Version 18 gleich  DBMS_SESSION.sleep verwenden zu können:
<code sql>
-- 
create or replace 
PROCEDURE sleep_plsql(p_seconds in number)
is
  v_120Parts pls_integer;
  v_LastRound pls_integer;
begin
   -- if we are on 18 use the DBMS_SESSION sleep methode!
   $IF DBMS_DB_VERSION.VER_LE_12 $THEN
  
          -- we need an oracle apex security context .-(
          -- put in your workspace
          apex_util.set_security_group_id (p_security_group_id => apex_util.find_security_group_id (p_workspace => 'DME'));
          -- 
          if p_seconds/120 > 1 then
              --- floor largest integer equal to or less than
              v_120Parts:=FLOOR(p_seconds/120);
              -- return the remainder 
              v_LastRound:=MOD( p_seconds, 120 );
          else
              v_120Parts:=0;
              v_LastRound:=p_seconds;
          end if;
          
          --  APEX_UTIL.PAUS cann only sleep may 120s!
          -- 
          if v_120Parts > 0 then
              for i in 1..v_120Parts
               loop
                 APEX_UTIL.PAUSE(120);
               end loop;
           end if;
           ---
           if v_LastRound > 0 then
              APEX_UTIL.PAUSE(v_LastRound);
           end if; 
    $ELSE
         DBMS_SESSION.sleep(p_seconds);
    $END
end;

--- testen

set serveroutput on
begin
dbms_output.put_line('-- Info start at '||to_char(systimestamp,'hh24:mi:SSxFF'));
sleep_plsql(11);
dbms_output.put_line('-- Info start at '||to_char(systimestamp,'hh24:mi:SSxFF'));
sleep_plsql(119);
dbms_output.put_line('-- Info start at '||to_char(systimestamp,'hh24:mi:SSxFF'));
sleep_plsql(123);
dbms_output.put_line('-- Info start at '||to_char(systimestamp,'hh24:mi:SSxFF'));
sleep_plsql(245);
dbms_output.put_line('-- Info start at '||to_char(systimestamp,'hh24:mi:SSxFF'));
sleep_plsql(545);
dbms_output.put_line('-- Info start at '||to_char(systimestamp,'hh24:mi:SSxFF'));
end;
/


</code>


===Problem ORA-20987: APEX - Package variable g_security_group_id must be set ====

Fehler:
<code sql>
ORA-20987: APEX - Package variable g_security_group_id must be set. - Contact your application administrator.
</code>

Lösung, Security ID setzen!
<code sql>
  -- we need an oracle apex security context .-(
  -- put in your workspace
  
  apex_util.set_security_group_id (p_security_group_id => apex_util.find_security_group_id (p_workspace => 'GPI'));
  
</code>

Das ist dann leider nicht so schön, damit wird der Code doch sehr von der Umgebung abhängig.


=== Wait Event - PL/SQL lock timer ===

In der DB ist <fc #800000>** "PL/SQL lock timer"**</fc> der Wait Event hinter diesem Aufruf in den Wait Statistiken. 

----

==== Java ====

Verwendung der Java Klasse "java.lang.Thread"


<code sql>
create or replace PROCEDURE sleep_java(p_milli_seconds in number) 
  AS 
  LANGUAGE JAVA NAME 'java.lang.Thread.sleep(long)';
</code>


<fc #800000>**Nachteil:**</fc> In den AWR / Statspack Berichten wird dann OVJM gerne als häufigster Wait aufgezeigt, sind noch andere Java Komponenten im Einsatz verfälscht das stark das Ergebniss.

Wie:
{{ :prog:oracle_ovjm_waits_with_java_sleep.png | OVJM Waits mit java.lang.Thread.sleep in der Datenbank }}

----

====DBMS_LOCK.sleep====



Nachteil:

  * Sicherheitsprobleme mit DBMS_LOCK habe dazu geführt das her keine Public Synonym in der DB für dieses Package vorliegt und damit ein direkter Grant benötigt wird!


Ab 18c auf keine Fall mehr verwenden! Gar nicht mehr offiziell in der Doku!

----

====DBMS_SESSION.sleep====

Ab der Version 18c!

Session "schläft" für n Sekunden, der Maximal Wert beträgt 3600 Sekunden (ansonsten gibt es ein ORA-38148: invalid time limit specified!)

<code sql>

begin
 dbms_session.sleep(10);
end;

</code>


----




==== Quellen ====


  * https://oracle-base.com/articles/18c/dbms_session-sleep-18c#dbms_lock
  * https://stackoverflow.com/questions/2561671/sleep-function-in-oracle
  * https://oracledeli.wordpress.com/2017/03/31/plsql-sleep-without-using-dbms_lock/
Gunther Oracle APEX und Datenbank Wiki

Benutzer-Werkzeuge

Webseiten-Werkzeuge

Seiten-Werkzeuge
